Алтернативно решение за DCount и DLookup с MS SQL Server Backend

Един от основните проблеми, с които се сблъскахме с Access, е използването на DLookup и DCount при използване на таблици на SQL Server. Наскоро работихме върху мигрирането на чисто решение на Access към SQL сървър и се натъкнахме на забавяне при зареждането на няколко формуляра. Това се дължи на използването на DLookup и DCount във VBA кода.

След това измислихме решение за бързо разрешаване на множеството случаи с няколко функции. Бяхме ръководени от друго решение, предоставено от Алън Браун, който проектира Extended DLookup тук, в тази връзка.

Решението на Алън подобрява производителността на DLookup чрез:

• Включително ред на сортиране, за да сте сигурни, че получавате желания резултат.
• Почистване след себе си.
• Правилно разграничава нула и низ с нулева дължина.
• Общо подобрение на производителността.

Сега направихме тази стъпка по-нататък, за да работим конкретно със SQL таблици или изгледи, те няма да работят с локални таблици на Access, тъй като специално използваме ADO връзка.

Включвам кода за двете функции, за да заменя DLookup и DCount

Public Function ESQLLookup(strField As String, strTable As String, Optional Criteria As Variant, _
    Optional OrderClause As Variant) As Variant
 
    Dim rs As ADODB.Recordset         'To retrieve the value to find.
    Dim rsMVF As ADODB.Recordset      'Child recordset to use for multi-value fields.
    Dim varResult As Variant        'Return value for function.
    Dim strSQL As String            'SQL statement.
    Dim strOut As String            'Output string to build up (multi-value field.)
    Dim lngLen As Long              'Length of string.
    Const strcSep = ","             'Separator between items in multi-value list.

    'Initialize to null.
    varResult = Null

    'Encapsulate Domain in brackets if none exist to allow special characters in the Domain string
    If Left$(strTable, 1) <> "[" Then
        strTable = "[" & strTable & "]"
    End If

    'Build the SQL string.
    strSQL = "SELECT TOP 1 " & strField & " FROM " & strTable
    If Not IsMissing(Criteria) Then
        strSQL = strSQL & " WHERE " & Criteria
    End If
    If Not IsMissing(OrderClause) Then
        strSQL = strSQL & " ORDER BY " & OrderClause
    End If
    strSQL = strSQL & ";"

    'Lookup the value.
    OpenMyRecordset rs, strSQL, rrOpenForwardOnly, rrLockReadOnly, True
    If rs.RecordCount > 0 Then
        'Will be an object if multi-value field.
        If VarType(rs(0)) = vbObject Then
            Set rsMVF = rs(0).Value
            Do While Not rsMVF.EOF
                If rs(0).Type = 101 Then        'dbAttachment
                    strOut = strOut & rsMVF!FileName & strcSep
                Else
                    strOut = strOut & rsMVF![Value].Value & strcSep
                End If
                rsMVF.MoveNext
            Loop
            'Remove trailing separator.
            lngLen = Len(strOut) - Len(strcSep)
            If lngLen > 0& Then
                varResult = Left(strOut, lngLen)
            End If
            Set rsMVF = Nothing
        Else
            'Not a multi-value field: just return the value.
            varResult = rs(0)
        End If
    End If
    rs.Close

    'Assign the return value.
    ESQLLookup = varResult
   
ErrEx.Catch 11 ' Division by Zero
    Debug.Print strSQL
    MsgBox "To troubleshoot this error, please evaluate the data that is being processed by:" _
            & vbCrLf & vbCrLf & strSQL, vbCritical, "Division by Zero Error"

ErrEx.CatchAll
    MsgBox "Error " & err.Number & ": " & err.Description, vbCritical, "Unexpected error"
    
ErrEx.Finally
    Set rs = Nothing

End Function

Public Function ESQLCount(strField As String, strTable As String, Optional Criteria As Variant) As Variant
    Dim rs As ADODB.Recordset         'To retrieve the value to find.
    Dim varResult As Variant        'Return value for function.
    Dim strSQL As String            'SQL statement.
    Dim lngLen As Long              'Length of string.

    'Initialize to null.
    varResult = Null

    'Encapsulate Domain in brackets if none exist to allow special characters in the Domain string
    If Left$(strTable, 1) <> "[" Then
        strTable = "[" & strTable & "]"
    End If

    'Build the SQL string.
    strSQL = "SELECT COUNT(" & strField & ") AS TotalCount FROM " & strTable
    If Not IsMissing(Criteria) Then
        strSQL = strSQL & " WHERE " & Criteria
    End If
    strSQL = strSQL & ";"

    'Lookup the value.
    OpenMyRecordset rs, strSQL, rrOpenForwardOnly, rrLockReadOnly, True
    
    varResult = Nz(rs.Fields("TotalCount"), 0)
    rs.Close

    'Assign the return value.
    ESQLCount = varResult
    
   
ErrEx.CatchAll
    MsgBox "Error " & err.Number & ": " & err.Description, vbCritical, "Unexpected error"
    Resume Next
    
ErrEx.Finally
    Set rs = Nothing

End Function

Ако имате екземпляр, който изисква използването на DSum, тогава можете лесно да адаптирате функцията DCount, за да ви даде необходимия резултат.

След прилагането на това решение открихме драматично подобрение в производителността на зареждането на формуляри и дизайнът ни помага да приложим това решение към множество проекти. Надявам се това решение да ви е полезно и ако имате други проблеми, с които можем да ви помогнем, моля, свържете се с нас на адрес accessexpert.com.