Oracle - В CLAUSE въпрос при използване с множество стойности, което го прави динамичен

За съжаление, ако вашият тип колекция е дефиниран в PL/SQL (а не в SQL), не можете да го използвате в SQL, защото SQL машината не знае как да се справи с него.

Ако вместо това сте дефинирали типа колекция в SQL, т.е.

CREATE TYPE varchar_tbl
    IS TABLE OF varchar2(40);

След това можете да направите нещо като

SELECT col1
  FROM table1 t1
 WHERE t1.id IN (SELECT column_value
                   FROM TABLE( <<variable of type varchar2_tbl>> ) )

в зависимост от версията на Oracle-- синтаксисът за използване на колекции в SQL е еволюирал с времето-- по-старите версии на Oracle имаха по-сложен синтаксис.

Можете да конвертирате PL/SQL асоциативен масив (вашият VARCHAR_ARRAY_TYPE) в колекция от SQL вложени таблици в PL/SQL, но това изисква повторение през асоциативния масив и попълване на вложената таблица, което е малко неприятно. Ако приемем, че VARCHAR_TBL вече е създадена колекция от вложени таблици

SQL> CREATE OR REPLACE TYPE varchar_tbl
         IS TABLE OF varchar2(40);

можете да конвертирате от асоциативния масив към вложената таблица и да използвате вложената таблица в SQL израз като този (използвайки таблицата SCOTT.EMP)

declare
  type varchar_array_type
    is table of varchar2(40)
       index by binary_integer;
  l_associative_array varchar_array_type;
  l_index             binary_integer;
  l_nested_table      varchar_tbl := new varchar_tbl();
  l_cnt               pls_integer;
begin
  l_associative_array( 1 ) := 'FORD';
  l_associative_array( 10 ) := 'JONES';
  l_associative_array( 100 ) := 'NOT A NAME';
  l_associative_array( 75 ) := 'SCOTT';
  l_index := l_associative_array.FIRST;
  while( l_index IS NOT NULL )
  loop
    l_nested_table.EXTEND;
    l_nested_table( l_nested_table.LAST ) :=
             l_associative_array( l_index );
    l_index := l_associative_array.NEXT( l_index );
  end loop;
  SELECT COUNT(*)
    INTO l_cnt
    FROM emp
   WHERE ename IN (SELECT column_value
                     FROM TABLE( l_nested_table ) );
  dbms_output.put_line( 'There are ' || l_cnt || ' employees with a matching name' );
end;

Тъй като преобразуването между типове колекции е малко трудно обаче, обикновено би било по-добре просто да използвате колекцията от вложени таблици (и да я предадете на съхранената процедура), освен ако няма конкретна причина, поради която е необходим асоциативният масив.