Предоставя ли Oracle начин за връщане на множество поднизове от ред на низ/clob, който е анализиран?

Може би нещо подобно:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN sys.dbms_debug_vc2coll PIPELINED
IS  
  pos PLS_INTEGER;
  lastpos PLS_INTEGER;
  element varchar(2000);
BEGIN
   lastpos := 1;
   pos := instr(longline, ',');

   while pos > 0 loop
      element := substr(longline, lastpos, pos - lastpos);
      lastpos := pos + 1;
      pos := instr(longline, ',', lastpos);
      pipe row(element);
   end loop;

   if lastpos <= length(longline) then
      pipe row (substr(longline, lastpos));
   end if;

   RETURN;
END;  
/

Това може да се използва по следния начин:

SQL> select * from table(explode('1,2,3'));

COLUMN_VALUE
---------------------------------------------
1
2
3
SQL>

Ако не сте на 11.x, трябва сами да дефинирате типа на връщане:

create type char_table as table of varchar(4000);

и променете декларацията на функцията на:

CREATE OR REPLACE FUNCTION explode(longline varchar)
  RETURN char_table pipelined
.....