Как да проверите версията на доставчика на oracle за ole-db. Доставчик на OraOLEDB.Oracle

Можете да използвате например инструмента RegDllView. Потърсете "OraOLEDB", резултатът може да бъде следният:

По-опростен подход би бил това да отидете до вашия ORACE_HOME\bin директория и намерете файла OraOLEDB??.dll . Проверете версията с щракване с десния бутон на мишката -> Свойства -> Подробности.

Въпреки това, вие просто получавате версията на файла, това не означава непременно, че тази DLL също е регистрирана и готова за използване.

Или използвайте този VBScript:

Option Explicit
Const HKEY_CLASSES_ROOT = &H80000000

Dim Key, strComputer, objRegistry, strPath, arrKeys, fso
Dim strKeyPath, strValueName, strValue, uValue, ver

Set fso = CreateObject("Scripting.FileSystemObject")

strComputer = "."
Set objRegistry = GetObject("winmgmts:\\" & strComputer & "\root\default:StdRegProv")
objRegistry.enumKey HKEY_CLASSES_ROOT, "CLSID", arrKeys

For Each key In arrKeys
    strKeyPath = "CLSID\" & key
    strValueName = "OLEDB_SERVICES"
    If objRegistry.GetDWordValue (HKEY_CLASSES_ROOT, strKeyPath, strValueName, uValue) = 0 Then  
        'get the (Default) value which is the name of the provider
        objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath, "", strValue
        If InStr(1, strValue, "OraOLEDB.Oracle", vbTextCompare) > 0 Then
            ' get expanded location
            objRegistry.GetStringValue HKEY_CLASSES_ROOT, strKeyPath & "\InprocServer32", "", strPath

            ver = fso.GetFileVersion(strPath)
            Wscript.Echo strValue & " @ " & strPath & " -> " & ver
        End If
    End If 
Next

Доставчикът на OLE DB може да съществува в 32-битова и/или в 64-битова, така че можете да изпълните скрипта два пъти:

C:\Windows\System32\cscript.exe Print_OLE.vbs
C:\Windows\SysWOW64\cscript.exe Print_OLE.vbs