Как да шифровате парола в Oracle?

Тук давам пример за криптиране на паролата в Oracle с помощта на пакета DBMS_CRYPTO.

За да демонстрирам това, създадох следната таблица за съхраняване на потребителски идентификатор (USER_ID) varchar2 тип данни и за съхраняване на необработен тип данни на криптирана парола (ENC_PSW).

Създаване на таблица

SET DEFINE OFF;
CREATE TABLE ENC_DATA
(
  USER_ID  VARCHAR2(20 BYTE),
  ENC_PSW  RAW(2000)
)
/

ALTER TABLE ENC_DATA ADD (
  CONSTRAINT ENC_DATA_PK
 PRIMARY KEY
 (USER_ID))
/

Пример за шифроване на парола в Oracle

Сега чрез следната програма PL/SQL ще съхраняваме паролата mypassword123 за потребителския идентификатор SCOTT . Ключът е жизненоважната част за криптирането, защото за да го дешифрирате, трябва да използвате същия ключ. Можете да използвате всеки буквено-цифров ключ с дължина 16 знака. За повече информация относно пакета DBMS_CRYPTO проверете документацията на Oracle.

SET SERVEROUTPUT ON;

DECLARE
   l_user_id    enc_data.USER_ID%TYPE := 'SCOTT';
   l_user_psw   VARCHAR2 (2000) := 'mypassword123';

   l_key        VARCHAR2 (2000) := '1234567890999999';
   l_mod NUMBER
         :=   DBMS_CRYPTO.ENCRYPT_AES128
            + DBMS_CRYPTO.CHAIN_CBC
            + DBMS_CRYPTO.PAD_PKCS5;
   l_enc        RAW (2000);
BEGIN
   l_user_psw :=
      DBMS_CRYPTO.encrypt (UTL_I18N.string_to_raw (l_user_psw, 'AL32UTF8'),
                           l_mod,
                           UTL_I18N.string_to_raw (l_key, 'AL32UTF8'));
   
      DBMS_OUTPUT.put_line ('Encrypted=' || l_user_psw);

   INSERT INTO enc_data (user_id, enc_psw)
       VALUES (l_user_id, l_user_psw);

   COMMIT;
END;
/

Изход

Encrypted=132BEDB1C2CDD8F23B5A619412C27B60
PL/SQL procedure successfully completed.

Проверете данните в таблицата ENC_DATA:

SELECT * FROM enc_data;

USER_ID	ENC_PSW
SCOTT	132BEDB1C2CDD8F23B5A619412C27B60

В горния пример той криптира паролата за потребителския идентификатор SCOTT и се съхранява в таблицата enc_data. Сега по-долу е програмата PL/SQL за извличане на паролата и декриптиране.

Пример за декриптиране на парола в Oracle

SET SERVEROUTPUT ON;

DECLARE
   l_user_id    enc_data.user_id%TYPE := 'SCOTT';
   l_user_psw   RAW (2000);

   l_key        VARCHAR2 (2000) := '1234567890999999';
   l_mod NUMBER
         :=   DBMS_CRYPTO.ENCRYPT_AES128
            + DBMS_CRYPTO.CHAIN_CBC
            + DBMS_CRYPTO.PAD_PKCS5;
   l_dec        RAW (2000);
BEGIN
   SELECT enc_psw
     INTO l_user_psw
     FROM enc_data
    WHERE user_id = l_user_id;

   l_dec :=
      DBMS_CRYPTO.decrypt (l_user_psw,
                           l_mod,
                           UTL_I18N.STRING_TO_RAW (l_key, 'AL32UTF8'));
   DBMS_OUTPUT.put_line ('Decrypted=' || UTL_I18N.raw_to_char (l_dec));
END;
/

Изход

Decrypted=mypassword123
PL/SQL procedure successfully completed.

Вижте също:

• Как да скрия парола в Oracle Forms?
• Променете потребителската парола на Sys в Oracle