Ще трябва да премахнете WITH SCHEMABINDING от вашите изгледи и таблични функции. За да ги идентифицирате, можете да направите запитване към INFORMATION_SCHEMA изгледи:
SELECT TABLE_SCHEMA, TABLE_NAME AS VIEW_NAME
FROM INFORMATION_SCHEMA.VIEWS
WHERE VIEW_DEFINITION LIKE '%SCHEMABINDING%'
SELECT ROUTINE_SCHEMA, ROUTINE_NAME
FROM INFORMATION_SCHEMA.ROUTINES
WHERE ROUTINE_DEFINITION LIKE '%SCHEMABINDING%'
- Първо архивирайте базата данни.
- Генерирайте
ALTERскрипт на всички обвързани със схема изгледи и функции. - Изтрийте думите „
WITH SCHEMABINDING“ от скрипта. - Стартирайте скрипта няколко пъти, докато всички референтни грешки бъдат разрешени.
- Променете сортирането на вашата база данни.
- Напишете скрипт и премахнете всички ограничения (ключове, проверки и настройки по подразбиране).
- Променете сортирането на всяка колона, като използвате скрипта по-долу.
- Пресъздайте ограничения.
- Накрая изпълнете оригиналния скрипт няколко пъти, за да активирате свързването на схема.
Можете да промените сортирането на всички колони с този скрипт:
DECLARE @collation nvarchar(128)
DECLARE @commands table ([SQL] nvarchar(max))
DECLARE @cursor cursor
DECLARE @sql nvarchar(max)
SET @collation = 'SQL_Latin1_General_CP1_CI_AS'
INSERT @commands ([SQL])
SELECT 'ALTER TABLE ' + QUOTENAME(c.TABLE_SCHEMA) +'.'+ QUOTENAME(c.TABLE_NAME)
+ ' ALTER COLUMN ' + QUOTENAME(c.COLUMN_NAME)
+ ' ' + c.DATA_TYPE
+ ISNULL('(' + LTRIM(STR(c.CHARACTER_MAXIMUM_LENGTH)) + ')', '')
+ ISNULL(' COLLATE ' + @collation, '')
+ ' ' + CASE c.IS_NULLABLE WHEN 'NO' THEN 'NOT ' ELSE '' END + 'NULL'
FROM INFORMATION_SCHEMA.COLUMNS c
INNER JOIN INFORMATION_SCHEMA.TABLES t
ON t.TABLE_SCHEMA = c.TABLE_SCHEMA AND t.TABLE_NAME = c.TABLE_NAME
WHERE t.TABLE_TYPE = 'BASE TABLE'
AND c.COLLATION_NAME <> @collation
SET @cursor = CURSOR FOR SELECT [SQL] FROM @commands
OPEN @cursor
FETCH NEXT FROM @cursor INTO @sql
WHILE @@FETCH_STATUS = 0
BEGIN
PRINT @sql
EXEC (@sql)
FETCH NEXT FROM @cursor INTO @sql
END
