Oracle Търсене във всички таблици във всички колони за низ

Най-малкото трябва да заявите ALL_TAB_COLUMNS, а не ALL_TABLES

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner, table_name, column_name FROM all_tab_columns) LOOP   
    EXECUTE IMMEDIATE    
      'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
      ' WHERE '||t.column_name||' = :1'   
       INTO match_count  
      USING v_search_string; 
    IF match_count > 0 THEN 
      dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
    END IF; 
  END LOOP;
END;
/

Ако търсите низ обаче, почти сигурно бихте искали да се ограничите до търсене на колони, които могат да съхраняват низ. Не би имало смисъл например да търсите низ в колона DATE. И освен ако нямате много априорни познания за това какво съдържа колона BLOB и способността да анализирате двоичното форматиране на колоната BLOB, няма да има смисъл да търсите низ в колона BLOB. Предвид това подозирам, че искате нещо повече като

DECLARE
  match_count integer;
  v_search_string varchar2(4000) := <<string you want to search for>>;
BEGIN  
  FOR t IN (SELECT owner,
                   table_name, 
                   column_name 
              FROM all_tab_columns
             WHERE data_type in ('CHAR', 'VARCHAR2', 'NCHAR', 'NVARCHAR2', 
                                 'CLOB', 'NCLOB') ) 
  LOOP   
    BEGIN
      EXECUTE IMMEDIATE    
        'SELECT COUNT(*) FROM '||t.owner || '.' || t.table_name||
        ' WHERE '||t.column_name||' = :1'   
         INTO match_count  
        USING v_search_string; 
      IF match_count > 0 THEN 
        dbms_output.put_line( t.owner || '.' || t.table_name ||' '||t.column_name||' '||match_count );
      END IF; 
    EXCEPTION
      WHEN others THEN
        dbms_output.put_line( 'Error encountered trying to read ' ||
                              t.column_name || ' from ' || 
                              t.owner || '.' || t.table_name );
    END;
  END LOOP;
END;
/

Разбира се, това ще бъде безумно бавно - ще сканирате напълно всяка таблица веднъж за всяка колона с низ в таблицата. При умерено големи таблици и умерен брой колони с низове това вероятно ще отнеме доста време.